Create *PGM Objects from Multiple *MODULE Objects

By:

Create PGM Objects from Multiple MODULE Objects

One of the biggest challenges in breaking your applications into multiple source members -- and therefore into multiple modules -- is setting up how to compile the source so that you end up with a program. This one activity, which can lead to enormous benefits in application maintenance, seems to keep many of us in the tired, old one-source-member-one-program model.

Meet Bob Cozzi and other System i world influencers to discuss your programming questions at this May's RPG World Conference [2]. May 4 to 7 in Las Vegas

There are two very different ways you can create *PGM objects from multiple *MODULE objects. The first is to compile each source member independently of the other, using the CRTRPGMOD command, and then bind everything together with the CRTPGM command. The second is a less-complex method that can be accomplished by doing a little work up front.

Let's look at both methods.

Method 1

A typical program is made up of four modules. Each module is, of course, created from a corresponding source member. Therefore, there are four source members that need to be compiled into *MODULE objects so that the resulting program can be created.

To compile these source members, you have to first determine which one of the four is the so-called entry module. With RPG IV, the entry module is the source member that contains the mainline calcs and, consequently, the code to execute the RPG cycle at startup. The secondary source members, when compiled, will contain only subprocedures and perhaps some global variables and maybe a file or two, but not the RPG cycle startup code.

Once you've identified the entry module (it should be the only one with mainline calcs), you can compile all four of the source members to produce *MODULE objects. You use the CRTRPGMOD command to do that. As an example, assume that you're doing an Order Entry program that is made up of the following modules:

ORDENTRY --The entry module, which contains mainline calcs and primary program logic
FINDCUST -- Contains subprocedures that search the customer file(s)
DATERTN – Contains subprocedures that perform date calculations
ORDPRICE -- Contains subprocedures that calculate pricing

If you look inside these source members, you should see standard Header specifications, as follows:

     H/IF DEFINED(*CRTBNDRPG)
     H   DFTACTGRP(*NO)
     H   ACTGRP('MYACTGRP')
     H/ELSE
     H  NOMAIN
     H/ENDIF
     H OPTION(*SRCSTMT:*NODEBUGIO)
     H BNDDIR('QC2LE')
     H EXTBININT(*YES)
     H OPENOPT(*INZOFL)
     H COPYRIGHT('2008 - Robert Cozzi, Jr. All rights reserved')

Click here to register [3] for the RPG World Conference; May 4 to 7, 2008.

To compile the four source members, you can use PDM option 15 or a CRTRPGMOD command. The command to compile each of them would be as follows:

CRTRPGMOD MODULE(ORDENTRY) SRCMBR(ORDENTRY) +
     SRCFILE(mylib/QRPGLESRC)
CRTRPGMOD MODULE(FINDCUST) SRCMBR(FINDCUST) +
     SRCFILE(mylib/QRPGLESRC)
CRTRPGMOD MODULE(DATERTN) SRCMBR(DATERTN) +
     SRCFILE(mylib/QRPGLESRC)
CRTRPGMOD MODULE(ORDPRICE) SRCMBR(ORDPRICE) +
     SRCFILE(mylib/QRPGLESRC)

These four CRTRPGMOD commands will produce corresponding *MODULE objects for each of the source members (assuming there are no coding errors).

To create a *PGM object from these modules, you need to issue a CRTPGM command and specify the names of the modules that will be included in the *PGM program, as follows:

CRTPGM  PGM(ORDENTRY) MODULE(ORDENTRY FINDCUST DATERTN ORDPRICE)

The CRTPGM command identifies the modules used to create the program. Note the order of the module names as listed on that parameter. The first module name is the name of the entry module and is the module that initially affects the creation of the program. If you want to use a different module as the entry module, you have to either specify that module name as the first one of the MODULE parameter or add a ENTMOD parameter to the CRTPGM command, as follows:

CRTPGM  PGM(ORDENTRY) ENTMOD(ORDENTRY) +      MODULE(DATERTN FINDCUST ORDENTRY ORDPRICE)

The ENTMOD keyword identifies the entry module that the CRTPGM uses when binding the modules together to create the *PGM object. When ENTMOD is used, the order of the module names on the MODULE parameter is irrelevant. If ENTMOD is not specified, the CRTPGM command defaults to ENTMOD(*FIRST) or the first module name on the MODULE parameter.

Once the CRTPGM finishes, you have an executable program. In this case, you have the ORDENTRY program that is made up of the four modules.

The problem I have with this method of compiling is that you have to remember each module used to create the program. This isn't too difficult if you are doing the development in one day or you have written it down somewhere, like on a yellow notepad.

But suppose you have a program that is made up of not three or four modules, but 11 or 15. Heck, nowadays even three or four modules is too much to remember. Just try using the CRTPGM command to create a program from seven modules, then sign off, come back the next day, and continue the development. You have to enter all seven module names on the MODULE parameter again. Needless to say, this isn't fun and leads us to the second method.

Method 2

The second method is a little easier and does not require that you remember the names of the secondary modules. This technique allows you to "write" the names of the module in a "notepad" and then refer to that notepad when compiling.

Of course, the notepad I'm talking about is a Binding Directory. Binding directories are simple, little objects on i5/OS that store the names of *MODULE and *SRVPGM (service program) objects. They store only the names of these objects, not the objects themselves.

Binding directories can be created any time, and you can add module and/or service program names to them whenever you want.

If you create a binding directory for each application and then add the names of all the application's *MODULE objects to that binding directory, you can get away with a much easier compile process. For example, if you create a binding directory named MYBD and add the names of the secondary modules (FINDCUST, DATERTN, and ORDPRICE) to this binding directory, you can avoid specifying that long list of module names on the CRTPGM command. Let's look at how this is accomplished.

To create a binding directory, use the CRTBNDDIR command as follows:

CRTBNDDIR  BNDDIR(MYAPPLIB/MYBD)

Then, add the names of the *MODULE objects to the binding directory. In this example, those names would be FINDCUST, DATERTN, and ORDPRICE. The ADDBNDDIRE command is used to add binding directory entries to a binding directory, as follows:

ADDBNDDIRE BNDDIR(MYBD) +
             OBJ((FINDCUST *MODULE) (DATERTN *MODULE) (ORDPRICE *MODULE))

At this point, the binding directory is created, and it contains the names of the secondary modules. If you haven't already compiled these modules, you'll need to do that now, as follows:

CRTRPGMOD MODULE(ORDENTRY) SRCMBR(ORDENTRY) +
     SRCFILE(mylib/QRPGLESRC)
CRTRPGMOD MODULE(FINDCUST) SRCMBR(FINDCUST) +
     SRCFILE(mylib/QRPGLESRC)
CRTRPGMOD MODULE(DATERTN) SRCMBR(DATERTN) +
     SRCFILE(mylib/QRPGLESRC)
CRTRPGMOD MODULE(ORDPRICE) SRCMBR(ORDPRICE) +
     SRCFILE(mylib/QRPGLESRC)

To create the ORDENTRY program, use the binding directory parameter in the CRTPGM command, as follows:

  CRTPGM PGM(ORDENTRY) MODULE(ORDENTRY) BNDDIR(MYBD)

As you can see, this technique makes the process a little easier. You only specify the program name, the main module name and the name of the binding directory. When you sign off and come back the next day, remembering MYBD is a whole lot easier to remember than a long list of module names. In addition, you can use PDM option 15 to compile the secondary source members. Since all the compiler parameters have been specified on the Header specification, a simple "15 enter" gets the source members compiled.

One Step Further

One other change that can be made is to add the new binding directory to the Header specification of the Entry module. To do this, alter that source member's Header specification, as follows:

     H/IF DEFINED(*CRTBNDRPG)
     H   DFTACTGRP(*NO)
     H   ACTGRP('MYACTGRP')
     H/ELSE
     H  NOMAIN
     H/ENDIF
     H OPTION(*SRCSTMT:*NODEBUGIO)
     H BNDDIR('QC2LE')
     H EXTBININT(*YES)
     H OPENOPT(*INZOFL)
     H COPYRIGHT('2008 - Robert Cozzi, Jr. All rights reserved')
         //  New binding directory keyword added below:     
     H  BNDDIR('MYBD')

By adding the BNDDIR('MYBD') keyword to the header specification you can simply use PDM option 14 (CRTBNDRPG) to compile the source member. This means a simple 14 <enter>" creates the program for you, no CRTRPGMOD followed by a complex CRTPGM. Just PDM option 14, and bam!

Bob Cozzi has been an RPG programmer since 1978. His best selling book, The Modern RPG IV Language along with earlier editions have sold more than 60,000 copies worldwide. Bob, along with authors Greg Veal (CL Programming for the IBM AS/400), Bob Tipton (Untangling IT), IBM's George Farr (Java for RPG Programmers) and others will be at the annual RPG World Conference [4] the place to get the kind of training and information you can take back and start using immediately.